#!/usr/local/bin/perl -w
#
# check_remote_metadevices
#
# by ATonns Wed Sep 25 17:52:36 EDT 2002
#
# monitor the custom mib associated with metachk
#
# $Id: check_remote_metadevices,v 1.3 2003/07/08 18:12:33 atonns Exp atonns $
#
# checm_remote_metadevices
# Copyright (C) 2003 - iVillage.com, Anthony Tonns
#
# This program is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License
# as published by the Free Software Foundation; either version 2
# of the License, or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
#

# perl setup
use strict;
use Getopt::Long;
use Net::SNMP ();
use CGI;
use IO::String;

use lib "/usr/local/nagios/libexec";
use utils qw($TIMEOUT %ERRORS &print_revision &support);
delete @ENV{'PATH', 'IFS', 'CDPATH', 'ENV', 'BASH_ENV'};
use NWPE;

# static variables
my $PROGNAME = "check_remote_metadevices";
my $version = '$Revision: 1.3 $';

# OIDs for the net-snmpd host resources mib
#
# iso.org.dod.internet.private.enterprises.ucdavis.60
my $baseoid = "1.3.6.1.4.1.2021.60";
my $baselen = length($baseoid) + 1;

# auth config stuff
my $username = "xxxxxxxx";
my $authpass = "xxxxxxxx";
my $privpass = "xxxxxxxx";

################################################################################
my $nwpe = NWPE->new($PROGNAME,$version);

@ARGV = $nwpe->get_args;
if ( ! exists $ARGV[0] ) {
	print "$PROGNAME: no args passed\n";
	$nwpe->quit($ERRORS{UNKNOWN});
}

# parse args
my ($opt_V,$opt_h,$opt_p,$opt_H,$opt_c,$opt_w,$opt_v);
Getopt::Long::Configure('bundling');
GetOptions(
	"V"   => \$opt_V, "version"    => \$opt_V,
	"h"   => \$opt_h, "help"       => \$opt_h,
	"v+"  => \$opt_v, "verbose+"   => \$opt_v,
	"H=s" => \$opt_H, "hostname=s" => \$opt_H,
);

# check args
if ( $opt_h )
	{ print_usage($nwpe,""); }
if ( $opt_V )
	{ print_revision($PROGNAME,$version); $nwpe->quit($ERRORS{OK}); }
if ( ! $opt_H )
	{ print_usage($nwpe,"must specify hostname with -H option."); }

# validate/rename input to sane variable names
my $hostname = $opt_H;

# set a timeout w/error message
$SIG{'ALRM'} = sub {
        print ("$PROGNAME: ERROR: alarm timeout\n");
        $nwpe->quit($ERRORS{UNKNOWN});
};
alarm($TIMEOUT);

# establish a session
my ($session,$error) = Net::SNMP->session(
	-hostname =>		$hostname,
	-version =>		"3",
	-username =>		$username,
	-authprotocol =>	"md5",
	-authpassword =>	$authpass,
	-privpassword =>	$privpass,
	-maxmsgsize =>		1048576,
	-timeout =>		$TIMEOUT,
	-retries =>		3,
);
if ( $error ) {
	print "$PROGNAME: session error: $error\n";
	$nwpe->quit($ERRORS{UNKNOWN});
}

# retreive the entire table
my $result = $session->get_table( -baseoid => $baseoid, );
if ( $session->error ) {
	print "$PROGNAME: get_table error: ".$session->error."\n";
	$session->close;
	$nwpe->quit($ERRORS{UNKNOWN});
}
$session->close;

## for debugging
## let's see it in order now
#foreach (sort keys %{$result}) {
#       my $key = $_;
#       my $val = ${$result}{$key};
#       print "$key -> $val\n";
#}

my $exitvalue_id = "$baseoid.100.1";
my $exitvalue = ${$result}{$exitvalue_id};
$exitvalue += 0;
if ( $exitvalue == 0 ) {
	print "metachk: all metadevices ok.\n";
	$nwpe->quit($ERRORS{OK});
}

my $output_id = "101";

my $output;
my $exitval = 0;

foreach (sort keys %{$result}) {
	my $key = $_;
	my ($column,$instance) = split(/\./, substr($key,$baselen));
	if ( $column eq $output_id ) {
		my $text = ${$result}{$key};
		if ( $text =~ /warning/ && $exitval < $ERRORS{WARNING}) {
			$exitval = $ERRORS{WARNING};
		}
		if ( $text =~ /critical/ && $exitval < $ERRORS{CRITICAL}) {
			$exitval = $ERRORS{CRITICAL};
		}
		$output .= "$text\n";
	}
}

print $output;
$nwpe->quit($exitval);

################################################################################

# how does this work again?
sub print_usage {
	my ($nwpe,$msg) = @_;
	my $PROGNAME = $nwpe->PROGNAME;
	my $version = $nwpe->version;
	if ( $msg ) { print "$PROGNAME: $msg\n\n"; }
	print_revision($PROGNAME,$version);
	print "Usage: $PROGNAME -H hostname\n";
	print "Usage: $PROGNAME --hostname=hostname\n";
	print "       ".' ' x length($PROGNAME) .
				     " [-v|--verbose -V|--version -h|--help]\n";
	$nwpe->quit($ERRORS{UNKNOWN});
}