#!/usr/local/bin/perl -w
#
# check_remote_interfaces
#
# by ATonns Mon Sep  9 14:15:23 EDT 2002
#
# monitor the interfaces OID in net-snmpd
#
# $Id: check_remote_interfaces,v 1.3 2003/07/08 18:12:33 atonns Exp atonns $
#
# check_remote_interfaces
# Copyright (C) 2003 - iVillage.com, Anthony Tonns
#
# This program is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License
# as published by the Free Software Foundation; either version 2
# of the License, or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
#

# perl setup
use strict;
use Getopt::Long;
use Net::SNMP ();
use CGI qw(-debug);
use IO::String;

use lib "/usr/local/nagios/libexec";
use utils qw($TIMEOUT %ERRORS &print_revision &support);
delete @ENV{'PATH', 'IFS', 'CDPATH', 'ENV', 'BASH_ENV'};
use NWPE;

# static variables
my $PROGNAME = "check_remote_interfaces";
my $version = '$Revision: 1.3 $';

# OIDs for the net-snmpd host resources mib
#
# iso.org.dod.internet.mgmt.mib-2.interfaces.ifTable.ifEntry 
my $baseoid = "1.3.6.1.2.1.2.2.1";
my $baselen = length($baseoid) + 1;
# ifDescr
my $oidkey     = "2";
# ifOperStatus
my $statuskey  = "8";
# ifOperStatus linkage from /usr/local/share/snmp/mibs/IF-MIB.txt
my %statuslinkage = (
	1 => "up",
	2 => "down",
	3 => "testing",
	4 => "unknown",
	5 => "dormant",
	6 => "notPresent",
	7 => "lowerLayerDown",
);

# auth config stuff
my $username = "xxxxxxxx";
my $authpass = "xxxxxxxx";
my $privpass = "xxxxxxxx";

################################################################################
my $nwpe = NWPE->new($PROGNAME,$version);

@ARGV = $nwpe->get_args;
if ( ! exists $ARGV[0] ) {
	print "$PROGNAME: no args passed\n";
	$nwpe->quit($ERRORS{UNKNOWN});
}

# parse args
my ($opt_V,$opt_h,$opt_H,$opt_v);
Getopt::Long::Configure('bundling');
GetOptions(
	"V"   => \$opt_V, "version"    => \$opt_V,
	"h"   => \$opt_h, "help"       => \$opt_h,
	"v+"  => \$opt_v, "verbose+"   => \$opt_v,
	"H=s" => \$opt_H, "hostname=s" => \$opt_H,
);

# check args
if ( $opt_h )
	{ print_usage($nwpe,""); }
if ( $opt_V )
	{ print_revision($PROGNAME,$version); $nwpe->quit($ERRORS{OK}); }
if ( ! $opt_H )
	{ print_usage($nwpe,"must specify hostname with -H option."); }

my $hostname = $opt_H;

# set a timeout w/error message
$SIG{'ALRM'} = sub {
        print ("$PROGNAME: ERROR: alarm timeout\n");
        $nwpe->quit($ERRORS{UNKNOWN});
};
alarm($TIMEOUT);

# establish a session
my ($session,$error) = Net::SNMP->session(
	-hostname =>		$hostname,
	-version =>		"3",
	-username =>		$username,
	-authprotocol =>	"md5",
	-authpassword =>	$authpass,
	-privpassword =>	$privpass,
	-maxmsgsize =>		1048576,
	-timeout =>		$TIMEOUT,
	-retries =>		3,
);
if ( $error ) {
	print "$PROGNAME: session error: $error\n";
	$nwpe->quit($ERRORS{UNKNOWN});
}

# retreive the entire ifTable
my $result = $session->get_table( -baseoid => $baseoid, );
if ( $session->error ) {
	print "$PROGNAME: get_table error: ".$session->error."\n";
	$session->close;
	$nwpe->quit($ERRORS{UNKNOWN});
}
$session->close;

my %map;	# from path to oid instance
my %data;	# data table re-hashed by path

# create a map based on the final oid for the column with $oidkey
foreach (sort keys %{$result}) {
	my $key = $_;
	my ($column,$instance) = split(/\./, substr($key,$baselen));
	if ( $column eq $oidkey ) {
		$map{$instance} = ${$result}{$key};
	}
}

# NOW reorder all the data in the table based on what was $oidkey's value
foreach (sort keys %{$result}) {
	my $key = $_;
	my ($column,$instance) = split(/\./, substr($key,$baselen));
	if ( $column ne $oidkey ) {
		$data{$map{$instance}}->{$column} = ${$result}{$key};
	}
}

## for debugging
## let's see it in order now
#foreach (sort keys %data) {
#	my $key = $_;
#	print "$key ";
#	print "	" if length($key) < 8;
#	foreach (sort keys %{$data{$key}}) {
#		my $subkey = $_;
#		my $val = $data{$key}->{$subkey};
#		print " $subkey:$val, ";
#	}
#	print "\n";
#}

# since we've checked all the sanity beforehand,
# start off assuming all is well
my $state = $ERRORS{OK};

# BUT just in case we'll declare a variable
my @badinterfaces;

# check all the interfaces
foreach (sort keys %data) {
	my $key = $_;
	# look at the ifOperStatus column
	my $ifOperStatus = ${$data{$key}}{$statuskey};
	if ( $ifOperStatus != 1 ) {
		$state = $ERRORS{CRITICAL};
		push(@badinterfaces,
			{ interface => $key, status => $ifOperStatus });
	}
}
#DEBUG
#push(@badinterfaces, { interface => "tony", status => 2, });
#$state = $ERRORS{CRITICAL};

# print text for the humans
my $statetxt;
foreach (keys(%ERRORS)) {
	my $key = $_;
	$statetxt=$key if ( $state == $ERRORS{$key} );
}

# the almighty output
print "Interfaces $statetxt";
if ( $state != $ERRORS{OK} ) {
	print " - ";
	while($#badinterfaces != -1) {
		my $int = shift(@badinterfaces);
		print "$$int{interface} = " . $statuslinkage{${$int}{status}} . ", ";
	}
}
print "\n";
$nwpe->quit($state);

################################################################################

# how does this work again?
sub print_usage {
	my ($nwpe,$msg) = @_;
	my $PROGNAME = $nwpe->PROGNAME;
	my $version = $nwpe->version;
	if ( $msg ) { print "$PROGNAME: $msg\n\n"; }
	print_revision($PROGNAME,$version);
	print "Usage: $PROGNAME -H hostname\n";
	print "Usage: $PROGNAME --hostname=hostname\n";
	print "       ".' ' x length($PROGNAME) .
				     " [-v|--verbose -V|--version -h|--help]\n";
	$nwpe->quit($ERRORS{UNKNOWN});
}