#!/usr/local/bin/perl -w
#
# check_remote_cpu
#
# by ATonns Mon Sep  9 14:15:23 EDT 2002
#
# monitor the systemStats OID in net-snmpd for CPU data
#

#
# $Id: check_remote_cpu,v 1.3 2003/07/08 18:12:33 atonns Exp atonns $
#
# check_remote_cpu
# Copyright (C) 2003 - iVillage.com, Anthony Tonns
#
# This program is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License
# as published by the Free Software Foundation; either version 2
# of the License, or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
#

# perl setup
use strict;
use Getopt::Long;
use Net::SNMP ();
use CGI;
use IO::String;

use lib "/usr/local/nagios/libexec";
use utils qw($TIMEOUT %ERRORS &print_revision &support);
delete @ENV{'PATH', 'IFS', 'CDPATH', 'ENV', 'BASH_ENV'};
use NWPE;

# static variables
my $PROGNAME = "check_remote_cpu";
my $version = '$Revision: 1.3 $';

# OIDs for the net-snmpd CPU data
#
# .iso.org.dod.internet.private.enterprises.ucdavis.systemStats

my %linkage = (
	"1.3.6.1.4.1.2021.11.9.0" => "user",
	"1.3.6.1.4.1.2021.11.10.0" => "system",
	"1.3.6.1.4.1.2021.11.11.0" => "idle",
);
my @oids = keys %linkage;

# auth config stuff
my $username = "xxxxxxxx";
my $authpass = "xxxxxxxx";
my $privpass = "xxxxxxxx";

################################################################################
my $nwpe = NWPE->new($PROGNAME,$version);

@ARGV = $nwpe->get_args;
if ( ! exists $ARGV[0] ) {
	print "$PROGNAME: no args passed\n";
	$nwpe->quit($ERRORS{UNKNOWN});
}

# parse args
my ($opt_V,$opt_h,$opt_H,$opt_c,$opt_w,$opt_v);
Getopt::Long::Configure('bundling');
GetOptions(
	"V"   => \$opt_V, "version"    => \$opt_V,
	"h"   => \$opt_h, "help"       => \$opt_h,
	"v+"  => \$opt_v, "verbose+"   => \$opt_v,
	"H=s" => \$opt_H, "hostname=s" => \$opt_H,
	"c=s" => \$opt_c, "critical=s" => \$opt_c,
	"w=s" => \$opt_w, "warning=s"  => \$opt_w,
);

# check args
if ( $opt_h )
	{ print_usage($nwpe,""); }
if ( $opt_V )
	{ print_revision($PROGNAME,$version); $nwpe->quit($ERRORS{OK}); }
if ( ! $opt_H )
	{ print_usage($nwpe,"must specify hostname with -H option."); }
if ( ! $opt_c )
	{ print_usage($nwpe,"must specify critical values with -c option."); }
if ( ! $opt_w )
	{ print_usage($nwpe,"must specify warning values with -w option."); }

# validate/rename input to sane variable names
my $hostname = $opt_H;
#
my $warn = $1 if ($opt_w =~ /([0-9]{1,2}\%?|100\%?)/);
($warn) || print_usage($nwpe,"Invalid warning threshold: $opt_w");
my $crit = $1 if ($opt_c =~ /([0-9]{1,2}\%?|100\%?)/);
($crit) || print_usage($nwpe,"Invalid critical threshold: $opt_c");

# remove % from options (not required, just convenient to the admin)
if ( substr($warn,-1,1) eq "%" ) {
        $warn = substr($warn,0,length($warn)-1) + 0;
}
if ( substr($crit,-1,1) eq "%" ) {
        $crit = substr($crit,0,length($crit)-1) + 0;
}

# last sanity check
if ( $warn > $crit ) {
	print_usage($nwpe,qq!Inconsistence in parameters: "warning cpu %" greater than "critical cpu %".!);
}

# set a timeout w/error message
$SIG{'ALRM'} = sub {
        print ("$PROGNAME: ERROR: alarm timeout\n");
        $nwpe->quit($ERRORS{UNKNOWN});
};
alarm($TIMEOUT);

# establish a session
my ($session,$error) = Net::SNMP->session(
	-hostname =>		$hostname,
	-version =>		"3",
	-username =>		$username,
	-authprotocol =>	"md5",
	-authpassword =>	$authpass,
	-privpassword =>	$privpass,
	-maxmsgsize =>		1048576,
	-timeout =>		$TIMEOUT,
	-retries =>		3,
);
if ( $error ) {
	print "$PROGNAME: session error: $error\n";
	$nwpe->quit($ERRORS{UNKNOWN});
}

# retreive the relevant OIDs
my $result = $session->get_request( -varbindlist => \@oids, );
if ( $session->error ) {
	print "$PROGNAME: get_request error: ".$session->error."\n";
	$session->close;
	$nwpe->quit($ERRORS{UNKNOWN});
}
$session->close;

# reorganize the data for coherent use
my %data;
foreach (sort keys %{$result}) {
        my $key = $_;
	$data{$linkage{$key}} = ${$result}{$key};
#DEBUG
#	print "$linkage{$key} CPU percentage = ${$result}{$key}\n";
}

# since we've checked all the sanity beforehand,
# start off assuming all is well
my $state = $ERRORS{OK};

my $total = $data{user} + $data{system};

# here's the checks
if ( $total > $warn || (100 - $data{idle}) > $warn ) {
	$state = $ERRORS{WARNING};
}
if ( $total > $crit || (100 - $data{idle}) > $crit ) {
	$state = $ERRORS{CRITICAL};
}

# print text for the humans
my $statetxt;
foreach (keys(%ERRORS)) {
	my $key = $_;
	$statetxt=$key if ( $state == $ERRORS{$key} );
}

# the almighty output
print "CPU usage - user: $data{user}\%, system: $data{system}\%, idle: $data{idle}\%";
print " - $statetxt" unless $state == $ERRORS{OK};
print "\n";
$nwpe->quit($state);

################################################################################

# how does this work again?
sub print_usage {
	my ($nwpe,$msg) = @_;
	my $PROGNAME = $nwpe->PROGNAME;
	my $version = $nwpe->version;
	if ( $msg ) { print "$PROGNAME: $msg\n\n"; }
	print_revision($PROGNAME,$version);
	print "Usage: $PROGNAME -H hostname -w warnlimit -c critlimit\n";
	print "Usage: $PROGNAME --hostname=hostname " .
				"--warning=warnlimit --critical=critlimit\n";
	print "       ".' ' x length($PROGNAME) .
				     " [-v|--verbose -V|--version -h|--help]\n";
	$nwpe->quit($ERRORS{UNKNOWN});
}