#!/usr/local/bin/perl -w
#
# check_pix_memory
#
# by ATonns Fri Jan 17 13:15:38 EST 2003
#
# monitor the critical PIX information
#
# $Id: check_pix_memory,v 1.3 2003/07/08 18:12:33 atonns Exp atonns $
#
# check_pix_memory - monitor Cisco PIX memory usage
# Copyright (C) 2003 - iVillage.com, Anthony Tonns
#
# This program is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License
# as published by the Free Software Foundation; either version 2
# of the License, or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
#

# perl setup
use strict;
use Getopt::Long;
use Net::SNMP ();
use CGI;
use IO::String;

use lib "/usr/local/nagios/libexec";
use utils qw($TIMEOUT %ERRORS &print_revision &support);
delete @ENV{'PATH', 'IFS', 'CDPATH', 'ENV', 'BASH_ENV'};
use NWPE;

# static variables
my $PROGNAME = "check_pix_memory";
my $version = '$Revision: 1.3 $';

# PIX Firewall OIDs 
#
# Memory usage
#	.5.1 is ciscoMemoryPoolUsed.1
#	.6.1 is ciscoMemoryPoolFree.1
#
# .iso.org.dod.internet.private.enterprises.cisco.ciscoMgmt
#	.ciscoMemoryPoolMIB.ciscoMemoryPoolObjects.ciscoMemoryPoolTable.ciscoMemoryPoolEntry
my $memtableoid = "1.3.6.1.4.1.9.9.48.1.1.1";

# auth config stuff
my $username = "xxxxxxxx";
my $authpass = "xxxxxxxx";
my $privpass = "xxxxxxxx";
my $community = "xxxxxxxx";

################################################################################
my $nwpe = NWPE->new($PROGNAME,$version);

@ARGV = $nwpe->get_args;
if ( ! exists $ARGV[0] ) {
	print "$PROGNAME: no args passed\n";
	$nwpe->quit($ERRORS{UNKNOWN});
}

# parse args
my ($opt_V,$opt_h,$opt_H,$opt_v,$opt_w,$opt_c);
Getopt::Long::Configure('bundling');
GetOptions(
	"V"   => \$opt_V, "version"    => \$opt_V,
	"h"   => \$opt_h, "help"       => \$opt_h,
	"v+"  => \$opt_v, "verbose+"   => \$opt_v,
	"H=s" => \$opt_H, "hostname=s" => \$opt_H,
	"w=s" => \$opt_w, "warning=s"  => \$opt_w,
	"c=s" => \$opt_c, "critical=s" => \$opt_c,
);

# check args
if ( $opt_h )
	{ print_usage($nwpe,""); }
if ( $opt_V )
	{ print_revision($PROGNAME,$version); $nwpe->quit($ERRORS{OK}); }
if ( ! $opt_H )
	{ print_usage($nwpe,"must specify hostname with -H option."); }

my $w_mem = $1 if ($opt_w =~ /(\d{1,2}\%?|100\%?)/);
($w_mem) || print_usage($nwpe,"Invalid memory warning threshold: $opt_w");

my $c_mem = $1 if ($opt_c =~ /(\d{1,2}\%?|100\%?)/);
($c_mem) || print_usage($nwpe,"Invalid memory critical threshold: $opt_c");

my $hostname = $opt_H;

# set a timeout w/error message
$SIG{'ALRM'} = sub {
        print ("$PROGNAME: ERROR: alarm timeout\n");
        $nwpe->quit($ERRORS{UNKNOWN});
};
alarm($TIMEOUT);

# establish a session
my ($session,$error) = Net::SNMP->session(
	-hostname =>		$hostname,
	-version =>		"1",
	-community =>		$community,
	-maxmsgsize =>		1048576,
	-timeout =>		$TIMEOUT,
	-retries =>		3,
);
if ( $error ) {
	print "$PROGNAME: session error: $error\n";
	$nwpe->quit($ERRORS{UNKNOWN});
}

my ($result,$key);

# retreive the entire ciscoMemoryPoolTable
$result = $session->get_table( -baseoid => $memtableoid, );
if ( $session->error ) {
	print "$PROGNAME: get_table error: ".$session->error."\n";
	$session->close;
	$nwpe->quit($ERRORS{UNKNOWN});
}
my ($curr_memused,$curr_memfree);
$key="$memtableoid.5.1";
if ( exists $result->{$key} ) {
	$curr_memused = $result->{$key};
}
else {
	print "$PROGNAME: missing memory used data\n";
	$session->close;
	$nwpe->quit($ERRORS{UNKNOWN});
}
$key="$memtableoid.6.1";
if ( exists $result->{$key} ) {
	$curr_memfree = $result->{$key};
}
else {
	print "$PROGNAME: missing memory free data\n";
	$session->close;
	$nwpe->quit($ERRORS{UNKNOWN});
}

$session->close;

# since we've checked all the sanity beforehand,
# start off assuming all is well
my $state = $ERRORS{OK};

my $curr_memtotal = $curr_memused + $curr_memfree;
if ( $curr_memtotal == 0 ) {
	print "$PROGNAME: total memory calculated is zero\n";
	$nwpe->quit($ERRORS{UNKNOWN});
}
my $curr_mem = int( ($curr_memused / $curr_memtotal) * 100 );

if ( substr($w_mem,-1,1) eq "%" ) {
        $w_mem = substr($w_mem,0,length($w_mem)-1) + 0;
}
if ( substr($c_mem,-1,1) eq "%" ) {
        $c_mem = substr($c_mem,0,length($c_mem)-1) + 0;
}

if ($w_mem < $curr_mem) {
	$state = $ERRORS{WARNING};
}

if ($c_mem < $curr_mem) {
	$state = $ERRORS{CRITICAL};
}

# print text for the humans
my $statetxt;
foreach (keys(%ERRORS)) {
	my $key = $_;
	$statetxt=$key if ( $state == $ERRORS{$key} );
}

# the almighty output
print "PIX Memory $statetxt - ";
print "$curr_mem\% ($curr_memused/$curr_memtotal)\n";
$nwpe->quit($state);

################################################################################

# how does this work again?
sub print_usage {
	my ($nwpe,$msg) = @_;
	my $PROGNAME = $nwpe->PROGNAME;
	my $version = $nwpe->version;
	if ( $msg ) { print "$PROGNAME: $msg\n\n"; }
	print_revision($PROGNAME,$version);
	print "Usage: $PROGNAME -H hostname " .
				"-w warnlimit -c critlimit\n";
	print "Usage: $PROGNAME --hostname=hostname " .
				"--warning=warnlimit --critical=critlimit\n";
	print "       ".' ' x length($PROGNAME) .
				     " [-v|--verbose -V|--version -h|--help]\n";
	$nwpe->quit($ERRORS{UNKNOWN});
}